【効率化】AutoHotKeyを使ってキーボード配列をカスタマイズする

2016/03/07 追記
ディレクトリを表す円記号(¥)が表記されていないミスがあったので修正。
¥→¥

野良黒 パソコンのキーボード配列を自由に設定する - Keyboard Butlerがオススメ!

上記エントリーで Keyboard Butler を使ってパソコンのキーボード配列を変更した。だが、筆者の環境では他ソフトとのコンフリクト (干渉による不具合)が多く、使用を断念した。

代わりに、KeySwapと AutoHotKeyを組み合わせることで同様の環境を再現した。
考えてみれば、マウスジェスチャーもahkを使った MouseGestureL を使っているのだから、ahkで完結させても構わなかったのだ。


■事前準備 - KeySwapで配列入れ替え

なぜ AutoHotKey で配列をいじるのに、このソフトが要るのか。
それは、AutoHotKey では半角/全角、CapsLock、かな(カナロック) などのLock系のキーへのキー割り当てはうまくいかないから。

こちらのソフトでそれらのキーボード配列を入れ替える。
レジストリを書き換えるので注意。レジストリの変更はOSの動きに影響を与えるので、意味がわからない人は使わないほうがいい。

愛とゆりの部屋
「KeySwap for XP」をダウンロード。
キーを入れ替えた後、ログオフ→ログイン、またはOSの再起動で有効化される。

筆者はCaps LockとEscを入れ替えるためだけに使用した。
これを入れ替える目的は、以下の通り。
  • Caps Lock:ランチャーのfenrirを呼び出すのに使用 (オプションから呼び出しキーは変更できるが、ついでなので)
  • Esc:Vimperator などで多用する

単純にキーボード配列を変更したいだけなら、すべてKeySwapで行うほうが楽かも。


■キーボード配列をカスタマイズするahk Script

AutoHotKey Unicode 64-bit V1.1.23.01 にて動作確認
AutoHotkey Downloads

ahkを使う利点は、配列を入れ替えるだけではなく、組み合わせも自由自在に行えること。
例えば、[無変換キー+u] や、[アプリケーションキー+←] などという無茶なショートカットキーも作れる。

今回のスクリプトは、「ホームポジションから動かない」がテーマ。押しやすい位置にある [無変換キー+○○] [変換キー+○○] を多用している。
これにより、↓↑←→の移動は元より、EnterやBackSpaceすらホームポジションから離れる必要がなくなった。

オマケとして、以下の組み合わせを付けて使い勝手をよくしてみた。
  • アプリケーションキー+↑↓←→:ボリューム / ミュート
  • F12 / Ctrl+F12:Google日本語入力の単語登録 / 辞書ツール起動

「アプリケーションキー」とは、キーボード右下のCtrlキーの横辺りにある、押すと右クリックのコンテキストメニューが出せるやつ。たまに使いたくなった時のために、[Ctrl+Appskey]でコンテキストメニューが出せるようにしてある。

Google日本語入力のツール起動は、もちろんGoogle日本語入力がインストールされていることが前提。
[F12]で単語登録、[Ctrl+F12]で辞書ツールが起動する。

見よう見まねで書いたため、間違いがあるかもしれません。
ご覧の方でご指摘の点がありましたら、どうぞご教示くださいませ。

;keyboard_customize_tbr.ahk
;http://tuberculin.blog102.fc2.com/
;AutoHotKeyU64 Ver1.1.23.1 にて動作確認
;LastUpdate 2016/01/28
;修飾キー ^ Ctrl , ! Alt , + Shift , # Win


;無変換+hjkl:アローキー
;ホームポジションでカーソル移動 (アローキー)
;Shiftも使える。選択反転可能。
vk1Dsc07B & k::Send, {Blind}{Up}
vk1Dsc07B & j::Send, {Blind}{Down}
vk1Dsc07B & h::Send, {Blind}{Left}
vk1Dsc07B & l::Send, {Blind}{Right}
;変換+hjkl:アローキー
vk1Csc079 & k::Send, {Blind}{Up}
vk1Csc079 & j::Send, {Blind}{Down}
vk1Csc079 & h::Send, {Blind}{Left}
vk1Csc079 & l::Send, {Blind}{Right}

;無変換+uio:カットとコピペ
;{Blind}はEvernoteなどでShiftと合わせて「テキストとして貼り付け」ができるように
vk1Dsc07B & u::Send, ^x
vk1Dsc07B & i::Send, {Blind}^c
vk1Dsc07B & o::Send, {Blind}^v
;変換+uio:カットとコピペ
vk1Csc079 & u::Send, ^x
vk1Csc079 & i::Send, {Blind}^c
vk1Csc079 & o::Send, {Blind}^v


;無変換:BackSpace / Shift+無変換:Delete
vk1Dsc07B::Send, {BS}
+vk1Dsc07B::Send, {Del}

;[F1]:無変換
F1::Send, {vk1Dsc07B}

;変換:Enter
vk1Csc079::Send, {Return}


;アプリケーションキー+↑↓←→:ボリューム / ミュート
;Ctrl+アプリケーションキーでコンテキストメニュー
AppsKey & Up::Send, {Volume_Up}
AppsKey & Down::Send, {Volume_Down}
AppsKey & Left::Send, {Volume_Mute}
AppsKey & Right::Send, {Volume_Mute}
^AppsKey::Send, {AppsKey}

;F12 / Ctrl+F12:Google日本語入力の単語登録 / 辞書ツール起動
F12::Run, "C:¥Program Files (x86)¥Google¥Google Japanese Input¥GoogleIMEJaTool.exe" --mode=word_register_dialog
^F12::Run, "C:¥Program Files (x86)¥Google¥Google Japanese Input¥GoogleIMEJaTool.exe" --mode=dictionary_tool


;カタカナ/ひらがな:変換
;不具合出るかも。出たら消去。Evernote上では動作しなかった。
sc070::Send, {vk1Csc079}

;CapsLock:sc03a / ひらがなカタカナ:vkF2sc070 
;AutoHotKeyで変更すると不具合のおそれあり
;KeySwap.exeなどでレジストリから変更するのが確実
;http://ahkwiki.net/Trouble#CapsLock.E3.82.84.E3.81.8B.E3.81.AA.E3.82.AD.E3.83.BC.E7.AD.89.E3.81.B8.E3.81.AE.E5.89.B2.E3.82.8A.E5.BD.93.E3.81.A6.E3.81.8C.E4.B8.8A.E6.89.8B.E3.81.8F.E3.81.84.E3.81.8B.E3.81.AA.E3.81.84


; 暴走防止
; 指定時間の間に実行できる最大のホットキー数を設定
; 70位にしておけば、コントロールパネルのキーボード設定で表示の間隔を最速にしていても問題ないはず 
; https://sites.google.com/site/autohotkeyjp/reference/commands/-MaxHotkeysPerInterval
#MaxHotkeysPerInterval 70
; https://sites.google.com/site/autohotkeyjp/reference/commands/-HotkeyInterval
; 指定時間の間に実行できる最大のホットキー数を設定
#HotkeyInterval 2000

今のところ快適に動いている。

関連記事



テーマ : フリーソフト
ジャンル : コンピュータ

コメントの投稿

非公開コメント

ブログ内検索
カスタム検索
プロフィール

兼業農家ツベル

Author:兼業農家ツベル
PC(パソコン)ときどきゲーム。ニュースも少々。

平成28年熊本地震に被災しました。今は元気です。

最近自分がアスペルガー症候群(AS)の特性が強いことがわかりました。

更新通知用:@tbrcln

カテゴリー
スポンサードリンク
●Amazonクーポン
「Amazonクーポン」のページにて、期間限定でAmazonのクーポン券がもらえます。
お買物前にチェックするとお得です。
タグクラウド

author by SUH
お知らせ
『.imtp.tachikawa.mopera.net』を含むhost、NTT docomoの提供する「mopera U」の環境からはアクセスできません。

野良黒 FC2を狙った迷惑なコメントが増殖中
スポンサードリンク
Amazonの検索が楽になるリンク
●【まとめ】 Amazonのバーゲン・セール・お買い得情報まとめ

●Amazonの「あわせ買い対象商品 」だけを検索する方法

●Amazonから「予約注文商品」だけを検索するためのリンク一覧
最近の記事
Archives
最新コメント
掲示板
FC2カウンター
リンク
RSSフィード